ABOUT Visual Basic Programmieren Programmierung Download Downloads Tips & Tricks Tipps & Tricks Know-How Praxis VB VBA Visual Basic for Applications VBS VBScript Scripting Windows ActiveX COM OLE API ComputerPC Microsoft Office Microsoft Office 97 Office 2000 Access Word Winword Excel Outlook Addins ASP Active Server Pages COMAddIns ActiveX-Controls OCX UserControl UserDocument Komponenten DLL EXE
Diese Seite wurde zuletzt aktualisiert am 02.06.2000

Diese Seite wurde zuletzt aktualisiert am 02.06.2000
Aktuell im ABOUT Visual Basic-MagazinGrundlagenwissen und TechnologienKnow How, Tipps und Tricks rund um Visual BasicActiveX-Komponenten, Controls, Klassen und mehr...AddIns für die Visual Basic-IDE und die VBA-IDEVBA-Programmierung in MS-Office und anderen AnwendungenScripting-Praxis für den Windows Scripting Host und das Scripting-ControlTools, Komponenten und Dienstleistungen des MarktesRessourcen für Programmierer (Bücher, Job-Börse)Dies&Das...

Themen und Stichwörter im ABOUT Visual Basic-Magazin
Code, Beispiele, Komponenten, Tools im Überblick, Shareware, Freeware
Ihre Service-Seite, Termine, Job-Börse
Melden Sie sich an, um in den vollen Genuss des ABOUT Visual Basic-Magazins zu kommen!
Informationen zum ABOUT Visual Basic-Magazin, Kontakt und Impressum

Zurück...

UDTs sammeln

Zurück...


Anzeige

(-hg) mailto:hg_udtcollection@aboutvb.de

Benutzerdefinierte Variabeln ("UDT"s - UserDefined Types) können nur dann in Collections oder als Elemente eines generischen Arrays (Array-Funktion) aufgenommen werden, wenn sie in einem öffentlichen Klassen-Modul (öffentliche Klasse, UserControl usw.) deklariert worden sind. Öffentliche Klassen-Module wiederum können nur in ActiveX-Projekten enthalten sein.

Über einen kleinen Umweg können Sie diese Beschränkung allerdings umgehen. Dieser Umweg führt über generische Arrays und zwei Hilfsfunktionen, die jeweils für den betreffenden benutzerdefinierten Variablentyp spezifisch angelegt werden werden müssen.

In der einen Hilfsfunktion werden die Elemente des UDTs mit der Array-Funktion als Array-Elemente eingelesen. In der anderen Hilfsfunktion werden die Array-Elemente dem den Elementen des Rückgabe-UDTs zugewiesen.

Dieses generische Array ist nun voll Variant-kompatibel und kann problemlos in andere Arrays oder in Collections aufgenommen werden.

Sehen Sie sich dazu das folgende kleine Beispiel an - zunächst die Deklaration des UDTs und die beiden Hilfsfunktionen, die Sie etwa in einem Standard-Modul deklarieren können:

Public Type ABC
  Counter As Long
  DateTime As Date
End Type

Public Function RABC(Arr As Variant) As ABC
  With RABC
    .Counter = Arr(0)
    .DateTime = Arr(1)
  End With
End Function

Public Function CABC(abcType As ABC) As Variant
  With abcType
    CABC = Array(.Counter, .DateTime)
  End With
End Function

Der Umweg über die beiden Hilfsfunktionen bringt nur minimalen Aufwand und so gut wie keine "syntaktischen Verrenkungen" mit sich, wie die folgende kleine Beispielanwendung zeigt. Hier werden im Click-Ereignis einer Schaltfläche neue UDT-Instanzen erzeugt und in eine Collection eingefügt. In einem weiteren Click-Ereignis einer Schaltfläche wird eine ListBox mit den Daten der in die Collection aufgenommenen UDTs gefüllt. Und im Click-Ereignis der ListBox schießlich wird ein spezifischer UDT aus der Collection ausgelesen, dessen Daten dann in einer MessageBox angezeigt werden.

Private mItems As Collection
Private mCounter As Long

Private Sub Form_Load()
  Set mItems = New Collection
End Sub

Private Sub cmdAdd_Click()
  Dim abcType As ABC
  Dim Key As String
  
  mCounter = mCounter + 1
  With abcType
    .Counter = mCounter
    .DateTime = Now
  End With
  Key = "Key" & mCounter
  mItems.Add CABC(abcType), Key
End Sub

Private Sub cmdShow_Click()
  Dim Item As Variant
  
  lst.Clear
  For Each Item In mItems
    With RABC(Item)
      lst.AddItem Format$(.Counter, "000") & " " & .DateTime
      lst.ItemData(lst.NewIndex) = .Counter
    End With
  Next
End Sub

Private Sub lst_Click()
  Dim abcType As ABC
  
  With lst
    If .ListIndex >= 0 Then
      abcType = RABC(mItems("Key" & .ItemData(.ListIndex)))
      With abcType
        MsgBox .Counter & vbCrLf & .DateTime
      End With
    End If
  End With
End Sub

Und wenn Sie wollen, können Sie die UDT-Arrays auch direkt (etwa aus der Collection heraus) verwenden. Praktischerweise sollten Sie dazu für die Indices der UDTL-Elemente in dem Array eine Enumeration deklarieren (neben der Deklaration des UDTs):

Public Enum ABCConstants
  abcCounter
  abcDateTime
End Enum

Der Code im Click-Ereignis der ListBox könnte dann statt dessen folgendermaßen aussehen:

Private Sub lst_Click()
  Dim Item As Variant

  With lst
    If .ListIndex >= 0 Then
      Item = mItems("Key" & .ItemData(.ListIndex))
      MsgBox Item(abcCounter) & vbCrLf & Item(abcDateTime)
    End If
  End With
End Sub

Beispiel-Projekt UDTCollection (udtcollection.zip - ca. 2,8 KB)


Artikel
Zum Download-Bereich dieses Artikel
Mail an den Autor dieses Artikels

KnowHow
Zur KnowHow-Übersicht

KnowHow-Themen
Themen - Allgemeines
Themen - Entwicklungsumgebung (VB-IDE)
Themen - Forms
Themen - Steuerelemente (Controls)
Themen - Grafik
Themen - Dateien
Themen - UserControls
Themen - Einsteiger-Tipps
Themen - Wussten Sie...?

Übersicht nach Titeln in alphabetischer Reihenfolge
Übersicht nach Erscheinungsdatum

Schnellsuche



Zum Seitenanfang

Copyright © 1999 - 2017 Harald M. Genauck, ip-pro gmbh  /  Impressum

Zum Seitenanfang

Zurück...

Zurück...

Download Internet Explorer