|
Eigentlich ist sie ja gut gemeint, die ToolTip-Anzeige des aktuellen Wertes eines Slider-Steuerelements aus den Microsoft Common Controls. Soll aber ein Slider-Steuerelement einmal etwas anderes repräsentieren als nur den einfachen Slider-Wert als simple Größenzahl, stört die Anzeige nur. Die "Rettung" ist nicht weit: Mittels einer Nachricht, die Sie über die API-Funktion SendMessage an das Slider-Steuerelement versenden, können Sie die Anzeige ausschalten.
Private Declare Function SendMessage Lib "user32" _
Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
ByVal wParam As Long, lParam As Any) As Long
' ...
SendMessage Slider1.hwnd, TBM_SETTOOLTIPS, 0, 0
Oder: einfacher zu merken - in eine Hilfsprozedur gepackt:
Public Sub SliderToolTipsOff(Slider As Slider)
Const TBM_SETTOOLTIPS = &H41D
SendMessage Slider.hwnd, TBM_SETTOOLTIPS, 0, 0
End Sub
Wenn Sie die ToolTips jedoch wieder einschalten wollen, dürfen Sie vor dem Abschalten nicht vergessen, das Handle des abzuschaltenden ToolTip-Fensters in Erfahrung zu bringen und zum Wiedereinschalten zwischenzuspeichern. Der Versand der Nachricht TBM_GETTOOLTIPS liefert Ihnen das Handle, das Sie in einer Variablen ablegen können. Um die ToolTip-Anzeige wieder einzuschalten, übergeben Sie anstelle von 0 (wie beim Abschalten) das abgelegte Handle im Parameter wParam beim Versand der Nachricht TBM_SETTOOLTIPS an das Slider-Steuerelement.
Private mToolTipWnd As Long
' ...
mToolTipWnd = SendMessage(Slider1.hwnd, TBM_GETTOOLTIPS, 0, 0)
' ...
SendMessage Slider1.hwnd, TBM_SETTOOLTIPS, mToolTipWnd, 0
Befindet sich auf dem Form (oder UserControl usw.) lediglich ein Slider-Steuerelement, können Sie zur Ablage eine private Variable im Allgemein-Teil des Forms verwenden. Ein paar mehr Slider können Sie sicher auch noch übersichtlich verwalten, wenn Sie eben mehrere Variablen anlegen. Ein wenig eleganter und sicherer bezüglich Verwechslungen können Sie das Aus- und Einschalten in einer Klasse verwalten.
Einer Instanz der Klasse SliderToolTip übergeben Sie beim Aufruf ihrer Init-Methode das betreffende Slider-Steuerelement. Danach brauchen Sie nur noch der Eigenschaft Enabled die Werte False oder True zuweisen, um die ToolTip-Anzeige aus- oder einzuschalten.
Private Declare Function SendMessage Lib "user32" _
Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
ByVal wParam As Long, lParam As Any) As Long
Private mToolTipWnd As Long
Private pControl As Slider
Private pEnabled As Boolean
Public Property Get Control() As Slider
Set Control = pControl
End Property
Public Property Get Enabled() As Boolean
Enabled = pEnabled
End Property
Public Property Let Enabled(New_Enabled As Boolean)
Const TBM_SETTOOLTIPS = &H41D
Const TBM_GETTOOLTIPS = &H41E
pEnabled = New_Enabled
Select Case pEnabled
Case False
mToolTipWnd = SendMessage(pControl.hwnd, TBM_GETTOOLTIPS, 0, 0)
SendMessage pControl.hwnd, TBM_SETTOOLTIPS, 0, 0
Case True
SendMessage pControl.hwnd, TBM_SETTOOLTIPS, mToolTipWnd, 0
End Select
End Property
Public Sub Init(Slider As Slider)
Set pControl = Slider
End Sub
|