ABOUT Visual Basic Programmieren Programmierung Download Downloads Tips & Tricks Tipps & Tricks Know-How Praxis VB VBA Visual Basic for Applications VBS VBScript Scripting Windows ActiveX COM OLE API ComputerPC Microsoft Office Microsoft Office 97 Office 2000 Access Word Winword Excel Outlook Addins ASP Active Server Pages COMAddIns ActiveX-Controls OCX UserControl UserDocument Komponenten DLL EXE
Diese Seite wurde zuletzt aktualisiert am 10.08.2001

Diese Seite wurde zuletzt aktualisiert am 10.08.2001
Aktuell im ABOUT Visual Basic-MagazinGrundlagenwissen und TechnologienKnow How, Tipps und Tricks rund um Visual BasicActiveX-Komponenten, Controls, Klassen und mehr...AddIns für die Visual Basic-IDE und die VBA-IDEVBA-Programmierung in MS-Office und anderen AnwendungenScripting-Praxis für den Windows Scripting Host und das Scripting-ControlTools, Komponenten und Dienstleistungen des MarktesRessourcen für Programmierer (Bücher, Job-Börse)Dies&Das...

Themen und Stichwörter im ABOUT Visual Basic-Magazin
Code, Beispiele, Komponenten, Tools im Überblick, Shareware, Freeware
Ihre Service-Seite, Termine, Job-Börse
Melden Sie sich an, um in den vollen Genuss des ABOUT Visual Basic-Magazins zu kommen!
Informationen zum ABOUT Visual Basic-Magazin, Kontakt und Impressum

Zurück...

Auflösung zuverlässig

Zurück...


Anzeige

(-hg) mailto:hg_screenex@aboutvb.de

Gewöhnlich können Sie die aktuelle Bildschirmgröße in der Maßeinheit TWIPS aus den Eigenschaften Width und Height des Screen-Objekts auslesen.

Breite = Screen.Width
Höhe = Screen.Height

Auch die aktuelle Bildschirmauflösung ("Große/Kleine Bildschirmschriften") in der Maßeinheit "dpi" können Sie ermitteln:

dpiX = 1440 / Screen.TwipsPerPixelX
dpiY = 1440 / Screen.TwipsPerPixelY

Allerdings kann es hin und wieder vorkommen, dass nach einer Änderung der Bildschirmgröße oder -auflösung durch den Anwender nicht mehr zuverlässig die aktuellen, korrekten Werte wiedergegeben werden. Vermutlich liegt dies an kleinen Unsauberkeiten im Zusammenspiel von manchem Bildschirmtreiber mit Visual Basic.

Die korrekten aktuellen Werte liefert dagegen immer die API-Funktion GetDeviceCaps. Sie wird für den Gerätekontext (DC) eines bestimmten Geräts aufgerufen, etwa eines Druckers oder eben des Bildschirms. Den Gerätekontext des Bildschirms erhalten Sie über die API-Funktion GetDC, der Sie als Fenster-Handle für den ganzen Bildschirm den Wert 0 übergeben. Nach der Verwendung des Gerätekontextes müssen Sie daran denken, ihn wieder mit der API-Funktion ReleaseDC freizugeben.

Neben dem Gerätekontext übergeben Sie der Funktion GetDeviceCaps einen Index, zu dem Sie den gewünschten Wert erhalten wollen. Zum Beispiel die Bildschirmhöhe und die Bildschirmbreite liefern auf diese Weise die beiden folgenden Hilfsfunktionen ScreenHeightPixels und ScreenWidthPixels:

Private Declare Function GetDC Lib "user32" _
 (ByVal hwnd As Long) As Long
Private Declare Function GetDeviceCaps Lib "gdi32" _
 (ByVal hdc As Long, ByVal nIndex As Long) As Long
Private Declare Function ReleaseDC Lib "user32" _
 (ByVal hwnd As Long, ByVal hdc As Long) As Long

Private Const HORZRES = 8
Private Const VERTRES = 10

Public Property Get ScreenHeightPixels() As Long
  Dim nDC As Long
  
  nDC = GetDC(0)
  ScreenHeightPixels = GetDeviceCaps(nDC, VERTRES)
  ReleaseDC 0, nDC
End Property

Public Property Get ScreenWidthPixels() As Long
  Dim nDC As Long
  
  nDC = GetDC(0)
  ScreenWidthPixels = GetDeviceCaps(nDC, HORZRES)
  ReleaseDC 0, nDC
End Property

Da von dem erwähnten Fehler auch die Eigenschaften Screen.TwipsPerPixelX und Screen.TwipsPerPixelY betroffen sein können, brauchen wir auch hierfür Ersatzfunktionen auf der Basis von GetDeviceCaps. Im Gegensatz zum Screen-Objekt liefert uns GetDeviceCaps direkt die vertikale und die horizontale Bildschirmauflösung:

Private Const LOGPIXELSX = 88
Private Const LOGPIXELSY = 90

Public Property Get dpiX() As Long
  Dim nDC As Long
  
  nDC = GetDC(0)
  dpiX = GetDeviceCaps(nDC, LOGPIXELSX)
  ReleaseDC 0, nDC
End Property

Public Property Get dpiY() As Long
  Dim nDC As Long
  
  nDC = GetDC(0)
  dpiY = GetDeviceCaps(nDC, LOGPIXELSY)
  ReleaseDC 0, nDC
End Property

Aus Bildschirmgröße in Pixels und aus Bildschirmauflösung in dpi ergeben sich die Alternativ-Werte für TwipsPerPixelX und TwipsPerPixelY und schließlich ebenso die Bildschirmauflösung in TWIPS:

Public Property Get TwipsPerPixelX() As Single
  Dim nDC As Long
  
  nDC = GetDC(0)
  TwipsPerPixelX = 1440 / GetDeviceCaps(nDC, LOGPIXELSX)
  ReleaseDC 0, nDC
End Property

Public Property Get TwipsPerPixelY() As Single
  Dim nDC As Long
  
  nDC = GetDC(0)
  TwipsPerPixelY = 1440 / GetDeviceCaps(nDC, LOGPIXELSY)
  ReleaseDC 0, nDC
End Property

Public Property Get ScreenHeight() As Single
  Dim nDC As Long
  
  nDC = GetDC(0)
  ScreenHeight = GetDeviceCaps(nDC, VERTRES) * _
   (1440 / GetDeviceCaps(nDC, LOGPIXELSY))
  ReleaseDC 0, nDC
End Property

Public Property Get ScreenWidth() As Single
  Dim nDC As Long
  
  nDC = GetDC(0)
  ScreenWidth = GetDeviceCaps(nDC, HORZRES) * _
   (1440 / GetDeviceCaps(nDC, LOGPIXELSX))
  ReleaseDC 0, nDC
End Property

Modul modScreenEx (modScreenEx.bas - ca. 2 KB)


Artikel
Zum Download-Bereich dieses Artikel
Mail an den Autor dieses Artikels

KnowHow
Zur KnowHow-Übersicht

KnowHow-Themen
Themen - Allgemeines
Themen - Entwicklungsumgebung (VB-IDE)
Themen - Forms
Themen - Steuerelemente (Controls)
Themen - Grafik
Themen - Dateien
Themen - UserControls
Themen - Einsteiger-Tipps
Themen - Wussten Sie...?

Übersicht nach Titeln in alphabetischer Reihenfolge
Übersicht nach Erscheinungsdatum

Schnellsuche




Zum Seitenanfang

Copyright © 1999 - 2017 Harald M. Genauck, ip-pro gmbh  /  Impressum

Zum Seitenanfang

Zurück...

Zurück...

Download Internet Explorer