|
Unabhängig von einem Form oder UserControl können Sie mit Hilfe von einigen wenigen API-Funktionen die tatsächliche Größe eines Bildes in einem Picture-Objekt bestimmen.
Mit der Funktion CreateCompatibleDC legen Sie zunächst einen allgemeinen Geräte-Kontext an. Als Fenster-Handle übergeben Sie hier den Wert 0, der die Erzeugung eines Fenster-unabhängigen und somit auf den ganzen Bildschirm bezogenen und dessen aktuelle Eigenschaften widerspiegelnden Geräte-Kontexts signalisiert. In diesen Geräte-Kontext legen Sie mit der Funktion SelectObject die Bitmap des Picture-Objekts, die von dessen Handle-Eigenschaft repräsentiert wird. Ein Aufruf der API-Funktion GetObject (zur Vermeidung von Konflikten mit der Visual Basic-eigenen Funktion GetObject per Alias-Deklaration in "GetObjectAPI" umgetauft) mit der Übergabe einer benutzerdefinierten Variablen des Typs BITMAP gibt in deren Elementen bmWidth und bmHeight die Breite und Höhe der Bitmap in Pixels zurück. Zu den insbesondere bei GDI-Aufrufen notwendigen abschließenden Aufräumarbeiten gehören die beiden letzten Aufrufe. Mit einem erneuten Aufruf von SelectObject legen Sie wieder das ursprünglich im Device-Kontext gewählte Objekt über das beim ersten Aufruf erhaltene Handle zurück. Den Device-Kontext selbst löschen Sie mit dem abschließenden Aufruf von DeleteDC.
Private Type BITMAP
bmType As Long
bmWidth As Long
bmHeight As Long
bmWidthBytes As Long
bmPlanes As Integer
bmBitsPixel As Integer
bmBits As Long
End Type
Private Declare Function CreateCompatibleDC Lib "gdi32" _
(ByVal hdc As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" _
(ByVal hdc As Long) As Long
Private Declare Function GetObjectAPI Lib "gdi32" _
Alias "GetObjectA" (ByVal hObject As Long, _
ByVal nCount As Long, lpObject As Any) As Long
Private Declare Function SelectObject Lib "gdi32" _
(ByVal hdc As Long, ByVal hObject As Long) As Long
Public Sub PictureSize(Picture As StdPicture, _
Optional Width As Long, Optional Height As Long)
Dim nDCOrigin As Long
Dim nObjOrigin As Long
Dim nBitmap As BITMAP
If Picture Is Nothing Then
Err.Raise 5
End If
nDCOrigin = CreateCompatibleDC(0)
nObjOrigin = SelectObject(nDCOrigin, Picture.Handle)
GetObjectAPI Picture.Handle, Len(nBitmap), nBitmap
SelectObject nDCOrigin, nObjOrigin
DeleteDC nDCOrigin
With nBitmap
Width = .bmWidth
Height = .bmHeight
End With
End Sub
Public Function PictureHeight(Picture As StdPicture) As Long
Dim nDCOrigin As Long
Dim nObjOrigin As Long
Dim nBitmap As BITMAP
If Picture Is Nothing Then
Err.Raise 5
End If
nDCOrigin = CreateCompatibleDC(0)
nObjOrigin = SelectObject(nDCOrigin, Picture.Handle)
GetObjectAPI Picture.Handle, Len(nBitmap), nBitmap
SelectObject nDCOrigin, nObjOrigin
DeleteDC nDCOrigin
PictureHeight = nBitmap.bmHeight
End Function
Public Function PictureWidth(Picture As StdPicture) As Long
Dim nDCOrigin As Long
Dim nObjOrigin As Long
Dim nBitmap As BITMAP
If Picture Is Nothing Then
Err.Raise 5
End If
nDCOrigin = CreateCompatibleDC(0)
nObjOrigin = SelectObject(nDCOrigin, Picture.Handle)
GetObjectAPI Picture.Handle, Len(nBitmap), nBitmap
SelectObject nDCOrigin, nObjOrigin
DeleteDC nDCOrigin
PictureWidth = nBitmap.bmWidth
End Function
|