ABOUT Visual Basic Programmieren Programmierung Download Downloads Tips & Tricks Tipps & Tricks Know-How Praxis VB VBA Visual Basic for Applications VBS VBScript Scripting Windows ActiveX COM OLE API ComputerPC Microsoft Office Microsoft Office 97 Office 2000 Access Word Winword Excel Outlook Addins ASP Active Server Pages COMAddIns ActiveX-Controls OCX UserControl UserDocument Komponenten DLL EXE
Diese Seite wurde zuletzt aktualisiert am 23.11.2001

Diese Seite wurde zuletzt aktualisiert am 23.11.2001
Aktuell im ABOUT Visual Basic-MagazinGrundlagenwissen und TechnologienKnow How, Tipps und Tricks rund um Visual BasicActiveX-Komponenten, Controls, Klassen und mehr...AddIns für die Visual Basic-IDE und die VBA-IDEVBA-Programmierung in MS-Office und anderen AnwendungenScripting-Praxis für den Windows Scripting Host und das Scripting-ControlTools, Komponenten und Dienstleistungen des MarktesRessourcen für Programmierer (Bücher, Job-Börse)Dies&Das...

Themen und Stichwörter im ABOUT Visual Basic-Magazin
Code, Beispiele, Komponenten, Tools im Überblick, Shareware, Freeware
Ihre Service-Seite, Termine, Job-Börse
Melden Sie sich an, um in den vollen Genuss des ABOUT Visual Basic-Magazins zu kommen!
Informationen zum ABOUT Visual Basic-Magazin, Kontakt und Impressum

Zurück...

Fehler-Lager

Zurück...


Anzeige

(-hg) mailto:hg_loaderr@aboutvb.de

Es gibt verschiedene Ereignisse, in denen zuvor eingeschaltete Fehlerbehandlungen nicht anspringen. So etwa reagiert eine vor dem Anzeigen eines Forms eingeschaltete Fehlerbehandlung nicht:

Public Sub Main()
  On Error GoTo MainError
  Form1.Show
  Exit Sub

MainError:
  Debug.Print Err.Description
End Sub

Der Fehler wäre beispielsweise im Load-Ereignis des Forms aufgetreten:

Private Sub Form_Load()
  Dim n As Double

  n = 1 / 0
End Sub

Zu erwarten wäre eigentlich, dass die Fehlerbehandlung in der oben stehenden Sub Main anspringt und die Fehlerbeschreibung "Division durch Null" im Direktfenster ausgegeben werden würde. Doch statt wird die Ausführung stur an der Fehlerstelle mit einer Fehlermeldung angehalten - die zuvor in Sub Main eingeschaltete Fehlerbehandlung wird ignoriert. Von dieser Ignoranz sind auch die Initialize-Ereignisse von Forms als auch von UserControls usw. betroffen.

Es gibt wohl keinen anderen Ausweg, als in diesen Ereignissen eine eigene Fehlerbehandlung einzuschalten, im Falle eines Fehlers die Fehlerdaten zwischenzuspeichern und diese im Anschluss an den übergeordneten Aufruf auszulesen. Zur Zwischenspeicherung dient die folgende einfache Klasse ErrClass. Mit einem Aufruf ihrer Init-Methode liest sie selbsttätig die aktuellen Werte des VB-Err-Objekts aus und speichert sie in privaten Variablen. Die Werte können über Nur-Lese-Eigenschaften abgefragt werden.

Private pNumber As Long
Private pSource As String
Private pDescription As String
Private pHelpFile As String
Private pHelpContext As Long

Public Property Get Number() As Long
  Number = pNumber
End Property

Public Property Get Source() As String
  Source = pSource
End Property

Public Property Get Description() As String
  Description = pDescription
End Property

Public Property Get HelpFile() As String
  HelpFile = pHelpFile
End Property

Public Property Get HelpContext() As Long
  HelpContext = pHelpContext
End Property

Public Sub Init()
  With Err
    pNumber = .Number
    pSource = .Source
    pDescription = .Description
    pHelpFile = .HelpFile
    pHelpContext = .HelpContext
  End With
End Sub

Eine Fehlerüberwachung eines Form_Load-Ereignisses könnte damit so ausgestattet werden - im Form:

Private mErrLoad As ErrClass

Public Property Get ErrLoad() As ErrClass
  If mErrLoad Is Nothing Then
    Set ErrLoad = New ErrClass
  Else
    Set ErrLoad = mErrLoad
  End If
End Property

Private Sub Form_Load()
  Dim x As Double
  
  On Error GoTo LoadErr
  x = 1 / 0
  Exit Sub
  
LoadErr:
  Set mErrLoad = New ErrClass
  mErrLoad.Init
End Sub

Und beispielsweise eine Sub Main-Prozedur, in der das Form zur Anzeige gebracht werden soll:

Public Sub Main()
  With frmTest
    .Show
    With .ErrLoad
      If .Number Then
        MsgBox .Description, vbCritical, "Fehler in 'frmTest.Show'"
      End If
    End With
  End With
End Sub

Beispuiel-Projekt LoadErr (loaderr.zip - ca. 3,1 KB)


Artikel
Zum Download-Bereich dieses Artikel
Mail an den Autor dieses Artikels

KnowHow
Zur KnowHow-Übersicht

KnowHow-Themen
Themen - Allgemeines
Themen - Entwicklungsumgebung (VB-IDE)
Themen - Forms
Themen - Steuerelemente (Controls)
Themen - Grafik
Themen - Dateien
Themen - UserControls
Themen - Einsteiger-Tipps
Themen - Wussten Sie...?

Übersicht nach Titeln in alphabetischer Reihenfolge
Übersicht nach Erscheinungsdatum

Schnellsuche




Zum Seitenanfang

Copyright © 1999 - 2017 Harald M. Genauck, ip-pro gmbh  /  Impressum

Zum Seitenanfang

Zurück...

Zurück...

Download Internet Explorer