ABOUT Visual Basic Programmieren Programmierung Download Downloads Tips & Tricks Tipps & Tricks Know-How Praxis VB VBA Visual Basic for Applications VBS VBScript Scripting Windows ActiveX COM OLE API ComputerPC Microsoft Office Microsoft Office 97 Office 2000 Access Word Winword Excel Outlook Addins ASP Active Server Pages COMAddIns ActiveX-Controls OCX UserControl UserDocument Komponenten DLL EXE
Diese Seite wurde zuletzt aktualisiert am 05.03.2001

Diese Seite wurde zuletzt aktualisiert am 05.03.2001
Aktuell im ABOUT Visual Basic-MagazinGrundlagenwissen und TechnologienKnow How, Tipps und Tricks rund um Visual BasicActiveX-Komponenten, Controls, Klassen und mehr...AddIns für die Visual Basic-IDE und die VBA-IDEVBA-Programmierung in MS-Office und anderen AnwendungenScripting-Praxis für den Windows Scripting Host und das Scripting-ControlTools, Komponenten und Dienstleistungen des MarktesRessourcen für Programmierer (Bücher, Job-Börse)Dies&Das...

Themen und Stichwörter im ABOUT Visual Basic-Magazin
Code, Beispiele, Komponenten, Tools im Überblick, Shareware, Freeware
Ihre Service-Seite, Termine, Job-Börse
Melden Sie sich an, um in den vollen Genuss des ABOUT Visual Basic-Magazins zu kommen!
Informationen zum ABOUT Visual Basic-Magazin, Kontakt und Impressum

Zurück...

Muster-Suche

Zurück...


Anzeige

(-hg) mailto:hg_instrpattern@aboutvb.de

Mit den VB-Funktionen MSDN-Library - VB InStrInStr und MSDN-Library - VB InStrRevInstrRev (letztere ist erst ab Visual Basic 6 verfügbar) können Sie nach den Vorkommen eines Teils-Strings in einem anderen String suchen. Wenn Sie dabei optional die Vergleichsmethode (CompareMethod) auf vbTextCompare setzen, wird sogar die Groß-/Kleinschreibung ignoriert. Eine Suche nach einem allgemeineren Muster, etwa nach einem Teil-String, der "wie ein Datum aussieht", ist damit nicht möglich.

Die beiden folgenden Funktionen sind um eine solche Muster-Suche erweiterte Funktionen. InstrPattern sucht dabei wie InStr vom Anfang her, während InstrPatternRev wie InstrRev vom Ende her sucht. Bei beiden können Sie optional die Start-Position und auch die Vergleichsmethode angeben.

Um den für die Vergleichsoperation benötigten Operator Like mit der Text-Vergleichsmethode verwenden zu können, muss der Vergleichsvorgang in ein eigenes Modul ausgelagert werden, in dem die Vergleichsmethode mit einem modul-globalen "Option Compare Text" gesetzt ist. Ein solches Modul finden Sie im Download zum Artikel Like Binary oder Text"Like Binary oder Text".

Damit sich der Umfang und die Geschwindigkeit der Funktionen in Grenzen halten, kann im Suchmuster lediglich das Fragezeichen als Platzhalter im Suchmuster verwendet werden. Ein Suchmuster, das "*"-Zeichen enthält, würde wegen der variablen Längen den Rahmen sprengen.

Public Enum ispTextCompareConstants
  ispBinaryCompare
  ispTextCompare
End Enum

Public Function InstrPattern(Text As String, Pattern As String, _
 Optional ByVal Start As Long = 1, _
 Optional ByVal CompareMethod As ispTextCompareConstants) As Long

  Dim l As Long
  Dim nPatternLength As Long
  Dim nTextLength As Long
  Dim nLast As Long
  
  If InStr(Pattern, "*") Then
    Err.Raise 380
  Else
    nPatternLength = Len(Pattern)
    nTextLength = Len(Text)
    If nTextLength >= nPatternLength Then
      nLast = nTextLength - nPatternLength + 1
      Select Case CompareMethod
        Case ispBinaryCompare
          For l = Start To nLast
            If Mid$(Text, l, nPatternLength) Like Pattern Then
              InstrPattern = l
              Exit Function
            End If
          Next 'l
        Case ispTextCompare
          For l = Start To nLast
            If LikeCompText(Mid$(Text, l, nPatternLength), Pattern) _
             Then
              InstrPattern = l
              Exit Function
            End If
          Next 'l
        Case Else
          Err.Raise 380
      End Select
    End If
  End If
End Function

Public Function InstrPatternRev(Text As String, Pattern As String, _
 Optional ByVal Start As Long = 1, _
 Optional ByVal CompareMethod As ispTextCompareConstants) As Long

  Dim l As Long
  Dim nPatternLength As Long
  Dim nTextLength As Long
  Dim nLast As Long
  
  If InStr(Pattern, "*") Then
    Err.Raise 380
  Else
    nPatternLength = Len(Pattern)
    nTextLength = Len(Text)
    If nTextLength >= nPatternLength Then
      nLast = nTextLength - nPatternLength + 1
      Select Case CompareMethod
        Case ispBinaryCompare
          For l = nLast To Start Step -1
            If Mid$(Text, l, nPatternLength) Like Pattern Then
              InstrPatternRev = l
              Exit Function
            End If
          Next 'l
        Case ispTextCompare
          For l = nLast To Start Step -1
            If LikeCompText(Mid$(Text, l, nPatternLength), Pattern) _
             Then
              InstrPatternRev = l
              Exit Function
            End If
          Next 'l
        Case Else
          Err.Raise 380
      End Select
    End If
  End If
End Function

Modul modInstrPattern (modInstrPattern.bas - ca. 2,9 KB)


Artikel
Zum Download-Bereich dieses Artikel
Mail an den Autor dieses Artikels

KnowHow
Zur KnowHow-Übersicht

KnowHow-Themen
Themen - Allgemeines
Themen - Entwicklungsumgebung (VB-IDE)
Themen - Forms
Themen - Steuerelemente (Controls)
Themen - Grafik
Themen - Dateien
Themen - UserControls
Themen - Einsteiger-Tipps
Themen - Wussten Sie...?

Übersicht nach Titeln in alphabetischer Reihenfolge
Übersicht nach Erscheinungsdatum

Schnellsuche




Zum Seitenanfang

Copyright © 1999 - 2017 Harald M. Genauck, ip-pro gmbh  /  Impressum

Zum Seitenanfang

Zurück...

Zurück...

Download Internet Explorer