(-hg) 

Wie wäre es mal mit ListBoxen oder ComboBoxen, in denen der Anwender immer weiter mit den Cursor-Tasten aufwärts und abwärts navigieren kann, ohne jemals an ein Ende zu stoßen? Selbstverständlich kann hier nicht die Rede von einem unendlichen Inhalt, von einer unendlichen Anzahl an Elementen der Listen sein. Es geht vielmehr um ein automatisches Umlaufen beim Navigieren. Dabei folgt abwärts auf das letzte Element wieder das erste Element, und aufwärts folgt auf das erste Element wieder das letzte Element.

Bei ComboBoxen ist diese Vorgabe recht einfach umzusetzen. Im KeyDown_Ereignis wird entsprechend der durch die gedrückte Taste gewünschten Bewegungsrichtung der ListIndex auf die jeweils "gegenüberliegende" Position gesetzt, wenn bereits das Ende bzw. der Anfang erreicht worden sind. Ausgelagert in eine Hilfsprozedur sähe dies so aus:

Public Sub ICBKeyDownSimple(ComboBox As ComboBox, _
 KeyCode As Integer, ByVal Shift As Integer)

  Select Case KeyCode
    Case vbKeyDown
      With ComboBox
        If Shift = 0 Then
          If .ListIndex = .ListCount - 1 Then
            .ListIndex = 0
            KeyCode = 0
          End If
        End If
      End With
    Case vbKeyUp
      With ComboBox
        If Shift = 0 Then
          If .ListIndex = 0 Then
            .ListIndex = .ListCount - 1
            KeyCode = 0
          End If
        End If
      End With
  End Select
End Sub

Für eine ListBox könnten Sie eine nahezu identische Prozedur verwenden, in der lediglich "ComboBox" durch "ListBox" ersetzt zu werden braucht, und bei der die Übergabe des Shift-Parameters entfallen kann, da eine ListBox ja nicht mit Alt+Pfeiltaste aufgeklappt werden kann:

Public Sub ILBKeyDownSimple(ListBox As ListBox, _
 KeyCode As Integer)

  Select Case KeyCode
    Case vbKeyDown
      With ListBox
        If .ListIndex = .ListCount - 1 Then
          .ListIndex = 0
          KeyCode = 0
        End If
      End With
    Case vbKeyUp
      With ListBox
        If .ListIndex = 0 Then
          .ListIndex = .ListCount - 1
          KeyCode = 0
        End If
      End With
  End Select
End Sub

Während man bei der ComboBox im geschlossenen Zustand der Umlauf optisch gar nicht weiter wahrzunehmen ist, ist er bei der geöffneten Liste wie auch bei einer mehrzeiligen ListBox deutlich sichtbar. Bei einer etwas pfiffigeren Variante werden daher die Elemente entsprechend umgehängt. Beim Abwärtsmarschieren wird immer das gerade oberste Element oben entfernt, unten angehängt und sogleich ausgewählt. Bei der Aufwärtsbewegung ins "Endlose" wird dem entsprechend das jeweils letzte Element umgehängt. Damit die ItemData-Inhalte der umgehängten Elemente bei einer ComboBox und einer ListBox und die Markierungen bei einer ListBox (vor allem beim CheckBox-Stil) nicht verloren gehen, werden diese Informationen beim Umhängen ebenfalls umkopiert.

Bei einer ListBox, deren Höhe genau an die Anzahl der enthaltenen Elemente angepasst ist, ist die optische Illusion perfekt.

Public Sub ICBKeyDown(ComboBox As ComboBox, _
 KeyCode As Integer, ByVal Shift As Integer)

  Select Case KeyCode
    Case vbKeyDown
      With ComboBox
        If Shift = 0 Then
          If .ListIndex = .ListCount - 1 Then
            LockWindowUpdate .Parent.hWnd
            .AddItem .List(0)
            .ItemData(.NewIndex) = .ItemData(0)
            .RemoveItem 0
            .ListIndex = .ListCount - 1
            KeyCode = 0
            LockWindowUpdate 0&
          End If
        End If
      End With
    Case vbKeyUp
      With ComboBox
        If Shift = 0 Then
          If .ListIndex = 0 Then
            LockWindowUpdate .Parent.hWnd
            .AddItem .List(.ListCount - 1), 0
            .ItemData(0) = .ItemData(.ListCount - 1)
            .RemoveItem .ListCount - 1
            .ListIndex = 0
            KeyCode = 0
            LockWindowUpdate 0&
          End If
        End If
      End With
  End Select
End Sub

Public Sub ILBKeyDown(ListBox As ListBox, _
 KeyCode As Integer)

  Select Case KeyCode
    Case vbKeyDown
      With ListBox
        If .ListIndex = .ListCount - 1 Then
          LockWindowUpdate .Parent.hWnd
          .AddItem .List(0)
          .ItemData(.NewIndex) = .ItemData(0)
          If .Style = vbListBoxCheckbox Then
            .Selected(.NewIndex) = .Selected(0)
          End If
          .RemoveItem 0
          .ListIndex = .ListCount - 1
          KeyCode = 0
          LockWindowUpdate 0&
        End If
      End With
    Case vbKeyUp
      With ListBox
        If .ListIndex = 0 Then
          LockWindowUpdate .Parent.hWnd
          .AddItem .List(.ListCount - 1), 0
          .ItemData(0) = .ItemData(.ListCount - 1)
          If .Style = vbListBoxCheckbox Then
            .Selected(0) = .Selected(.ListCount - 1)
          End If
          .RemoveItem .ListCount - 1
          .ListIndex = 0
          KeyCode = 0
          LockWindowUpdate 0&
        End If
      End With
  End Select
End Sub

Copyright © 1999 - 2011 Harald M. Genauck, ip-pro gmbh  /  Impressum