ABOUT Visual Basic Programmieren Programmierung Download Downloads Tips & Tricks Tipps & Tricks Know-How Praxis VB VBA Visual Basic for Applications VBS VBScript Scripting Windows ActiveX COM OLE API ComputerPC Microsoft Office Microsoft Office 97 Office 2000 Access Word Winword Excel Outlook Addins ASP Active Server Pages COMAddIns ActiveX-Controls OCX UserControl UserDocument Komponenten DLL EXE
Diese Seite wurde zuletzt aktualisiert am 31.01.2001

Diese Seite wurde zuletzt aktualisiert am 31.01.2001
Aktuell im ABOUT Visual Basic-MagazinGrundlagenwissen und TechnologienKnow How, Tipps und Tricks rund um Visual BasicActiveX-Komponenten, Controls, Klassen und mehr...AddIns für die Visual Basic-IDE und die VBA-IDEVBA-Programmierung in MS-Office und anderen AnwendungenScripting-Praxis für den Windows Scripting Host und das Scripting-ControlTools, Komponenten und Dienstleistungen des MarktesRessourcen für Programmierer (Bücher, Job-Börse)Dies&Das...

Themen und Stichwörter im ABOUT Visual Basic-Magazin
Code, Beispiele, Komponenten, Tools im Überblick, Shareware, Freeware
Ihre Service-Seite, Termine, Job-Börse
Melden Sie sich an, um in den vollen Genuss des ABOUT Visual Basic-Magazins zu kommen!
Informationen zum ABOUT Visual Basic-Magazin, Kontakt und Impressum

Zurück...

Früher als später

Zurück...


Anzeige

(-hg) mailto:hg_datecomp@aboutvb.de

Wahrscheinlich sind Sie es gewohnt, dem einfachen Vergleich zweier Datumswerte blind zu vertrauen:

"01.01.2001" > "01.01.2000"

ergibt genauso "Wahr" wie

"01.01.2001" < "01.01.2002"

Auch mit Datumswerten, die einen Uhrzeit-Anteil enthalten, funktioniert das offensichtlich problemlos, zumindest bei Werten aus einer einigermaßen nahen Vergangenheit und bei allen Werten der Zukunft. Bei Datumswerten mit Uhrzeit-Anteil, die vor dem 30.12.1899 liegen, schlagen die Vergleiche fehl, wenn es sich bei beiden verglichenen Werten um den gleichen Tag handelt und sich nur die Uhrzeiten unterscheiden:

"01.01.1800 08:00" < "01.01.1800 14:00"

ergibt unerwarteterweise "Falsch".

Dennoch ist das Ergebnis völlig korrekt, wenn Sie in Betracht ziehen, wie Datums- und Zeitwerte intern in Visual Basic repräsentiert werden, und wie diese Repräsentation tatsächlich definiert ist.

Um einen Wert des Datentyps Date im Arbeitsspeicher (und genau so natürlich auch auf Speichermedien) unabhängig von der Formatierung ablegen zu können, wird er in "serialisierter" Form dargestellt, als Wert des Datentyps Double. Die Definition dazu besagt, dass das Datum im ganzzahligen Anteil des Double-Wertes abgelegt wird. Dabei entspricht der Wert 0 dem Datum "30.12.1899", wobei das frühestmögliche Datum der "01.01.100" ist. Die Uhrzeit wird zusätzlich als einfacher Dezimalbruch eines ganzen Tages im Nachkomma-Anteil des Double-Wertes abgelegt, wobei der Dezimalbruch 0,5 die Mittagszeit 12 Uhr darstellt. Der Wert 1,5 entspricht damit dem "31.12.1899 12:00".

Bei Datumswerten mit Uhrzeit-Anteil vor dem 30.12.1899 ist diese Definition somit einfach nur ganz strikt anzuwenden. Sie erlaubt zwar negative Datumswerte, aber von einer negativen Uhrzeit ist nicht die Rede. Noch einmal kurz und eindeutig festgehalten:

Der Nachkomma-Anteil stellt immer nur die Uhrzeit des vom ganzzahligen Anteil repräsentierten Tages dar.

So bedeutet der Wert -0,5 nicht etwa "29.12.1899 12:00", sondern 12 Uhr des Tages 0, also "30.12.1899 12:00" - genau so wie auch 0,5. Denn der Dezimalbruch 0,5 ist und bleibt 12 Uhr, egal ob vom Tag +0 oder vom Tag -0.

Die unweigerliche Konsequenz daraus ist schließlich, dass Sie bei gleichen Datumswerten vor dem 30.12.1899 mit unterschiedlichem Uhrzeit-Anteil den Wert erst einmal zerlegen müssen, ehe Sie den Vergleich anstellen können.

Die folgende Funktion DateComp erledigt diesen Vergleich für alle Datumswerte, unabhängig davon, ob sie vor oder nach dem 30.12.1899 liegen. Nach dem Muster der Visual Basic-Funktion StrComp gibt sie -1 zurück, wenn der erste übergebene Wert der frühere ist. Ist der erste übergebene Wert der spätere, gibt sie 1 zurück. Sind beide Werte gleich, gibt sie 0 zurück.

Public Function DateComp(Date1 As Date, Date2 As Date) As Integer
  Dim nDateDbl1 As Double
  Dim nDateDbl2 As Double
  Dim nDayPart1 As Long
  Dim nDayPart2 As Long
  Dim nTimePart1 As Double
  Dim nTimePart2 As Double
  
  nDateDbl1 = CDbl(Date1)
  nDateDbl2 = CDbl(Date2)
  Select Case -1
    Case Sgn(nDateDbl1), Sgn(nDateDbl2)
      nDayPart1 = Fix(nDateDbl1)
      nDayPart2 = Fix(nDateDbl2)
      Select Case True
        Case nDayPart1 < nDayPart2
          DateComp = -1
        Case nDayPart1 = nDayPart2
          nTimePart1 = CDbl(nDateDbl1 - nDayPart1)
          nTimePart2 = CDbl(nDateDbl2 - nDayPart2)
          Select Case True
            Case nTimePart1 < nTimePart2
              DateComp = 1
            Case nTimePart1 = nTimePart2
            Case nTimePart1 > nTimePart2
              DateComp = -1
          End Select
        Case nDayPart1 > nDayPart2
          DateComp = 1
      End Select
    Case Else
      Select Case True
        Case Date1 < Date2
          DateComp = -1
        Case Date1 = Date2
        Case Date1 > Date2
          DateComp = 1
      End Select
  End Select
End Function

Modul modDateComp (modDateComp.bas - ca. 1,6 KB)


Artikel
Zum Download-Bereich dieses Artikel
Mail an den Autor dieses Artikels

KnowHow
Zur KnowHow-Übersicht

KnowHow-Themen
Themen - Allgemeines
Themen - Entwicklungsumgebung (VB-IDE)
Themen - Forms
Themen - Steuerelemente (Controls)
Themen - Grafik
Themen - Dateien
Themen - UserControls
Themen - Einsteiger-Tipps
Themen - Wussten Sie...?

Übersicht nach Titeln in alphabetischer Reihenfolge
Übersicht nach Erscheinungsdatum

Schnellsuche




Zum Seitenanfang

Copyright © 1999 - 2017 Harald M. Genauck, ip-pro gmbh  /  Impressum

Zum Seitenanfang

Zurück...

Zurück...

Download Internet Explorer