|
Auch Steuerelemente eines Steuerelementfeldes (Control-Array) lassen sich wie jedes Steuerelement über den Namen als Schlüssel in der Controls-Collection eines Forms (oder UserControls usw.) ansprechen:
Einfaches Steuerelement:
Debug.Print Controls("Command1").Caption
Zum Beispiel Element 0 eines Steuerelementfeldes:
Debug.Print Controls("Command1")(0).Caption
Sie können diese Weise des Zugriffs auch zum Laden oder Entladen von Elementen eines Steuerelementfeldes verwenden
Load Controls("Command1")(1)
und natürlich auch gleich darauf zugreifen:
With Controls("Command1")(1)
.Move ...
.Visible = True
End With
Und wieder entladen:
Unload Controls("Command1")(1)
Die Ermittlung des höchsten bzw. niedrigsten Indexes eines Steuerelementfeldes geht ebenfalls:
Debug.Print Controls("Command1").ubound
Debug.Print Controls("Command1").lbound
Auch wird so beispielsweise das Laden von "Zwillingen" zu allen bereits vorhandenen Elementen in Steuerelementfeldern eine einfache Angelegenheit:
Dim nControl
Dim nIndex As Integer
Me.Show
DoEvents
On Error Resume Next
For Each nControl In Controls
nIndex = nControl.Index
If Err.Number Then
Err.Clear
Else
nIndex = Controls(nControl.Name).ubound + 1
Load Controls(nControl.Name)(nIndex)
With Controls(nControl.Name)(nIndex)
.Left = nControl.Left + nControl.Width
.Visible = True
End With
End If
Next
Sie brauchen dabei nicht zu fürchten, dass die Schleife endlos neue Steuerelemente erzeugt, wenn ständig neue Steuerelemente geladen werden und die Controls-Collection damit ständig weiter wächst. Die For...Each-Schleife wird nämlich lediglich für die Elemente durchlaufen, die zu Beginn darin enthalten waren.
Erst bei einem Folgedurchlauf werden die hinzugekommen Steuerelemente berücksichtigt - so etwa, um anschließend "Vierlinge" zu erzeugen, die geladenen Steuerelemente der Steuerelementfelder noch einmal zu verdoppeln:
On Error Resume Next
For Each nControl In Controls
nIndex = nControl.Index
If Err.Number Then
Err.Clear
Else
nIndex = Controls(nControl.Name).ubound + 1
Load Controls(nControl.Name)(nIndex)
With Controls(nControl.Name)(nIndex)
.Move nControl.Left, nControl.Top + nControl.Height
.Visible = True
End With
End If
Next
Der Index in der jeweils ersten Zeile der beiden obenstehenden Schleifen wird gelesen, um die Steuerelemente auszuschließen, die nicht ein Element eines Steuerelementfeldes sind. bei diesen löst der Zugriff auf die Index-Eigenschaft einen Laufzeitfehler aus, dessen Auftreten zur Unterscheidung herangezogen wird.
|