ABOUT Visual Basic Programmieren Programmierung Download Downloads Tips & Tricks Tipps & Tricks Know-How Praxis VB VBA Visual Basic for Applications VBS VBScript Scripting Windows ActiveX COM OLE API ComputerPC Microsoft Office Microsoft Office 97 Office 2000 Access Word Winword Excel Outlook Addins ASP Active Server Pages COMAddIns ActiveX-Controls OCX UserControl UserDocument Komponenten DLL EXE
Diese Seite wurde zuletzt aktualisiert am 20.06.2001

Diese Seite wurde zuletzt aktualisiert am 20.06.2001
Aktuell im ABOUT Visual Basic-MagazinGrundlagenwissen und TechnologienKnow How, Tipps und Tricks rund um Visual BasicActiveX-Komponenten, Controls, Klassen und mehr...AddIns für die Visual Basic-IDE und die VBA-IDEVBA-Programmierung in MS-Office und anderen AnwendungenScripting-Praxis für den Windows Scripting Host und das Scripting-ControlTools, Komponenten und Dienstleistungen des MarktesRessourcen für Programmierer (Bücher, Job-Börse)Dies&Das...

Themen und Stichwörter im ABOUT Visual Basic-Magazin
Code, Beispiele, Komponenten, Tools im Überblick, Shareware, Freeware
Ihre Service-Seite, Termine, Job-Börse
Melden Sie sich an, um in den vollen Genuss des ABOUT Visual Basic-Magazins zu kommen!
Informationen zum ABOUT Visual Basic-Magazin, Kontakt und Impressum

Zurück...

Alternative Rahmen

Zurück...


Anzeige

(-hg) mailto:hg_borderstyle@aboutvb.de

PictureBox, Frame und eine Reihe anderer Steuerelemente bieten nur wenige Möglichkeiten, das Aussehen ihres Rahmens einzustellen. Meistens beschränken sich diese Einstellungen auf eine flachen, rahmenlose oder versenkte Darstellung. Sie können zwar auf andere Weise für Rahmen sorgen, etwa indem Sie mittels der API-Funktion DrawEdge einen individuellen Rahmen um ein Steuerelement herum - oder bei einer PictureBox direkt hinein - zeichnen (siehe: Steuerelemente mit 3D-Rahmen"Steuerelemente mit 3D-Rahmen"). Doch das ist relativ aufwändig.

Wenn Ihnen lediglich zwei verschiedene weitere Rahmenstile reichen, nämlich mit einem etwas dickeren, erhabenen Rahmen oder mit einer dünnen Versenkung, können Sie diese Rahmenstile den betreffenden Steuerelementen auch selbst zuweisen. Dazu ändern Sie die Stil-Informationen eines Steuerelement direkt. Die bereits vorhanden, gesetzten Stil-Informationen eines Steuerelements (Fensters) erhalten Sie über die API-Funktion MSDN-Library - API GetWindowLongGetWindowLong mit der Angabe GW_STYLE bzw. GW_EXSTYLE (je nach dem, welchen Stil Sie zu setzen beabsichtigen). Nach der Verknüpfung des gelieferten Stile-Wertes mit dem neuen Stil wird der Wert mit der API-Funktion MSDN-Library - API SetWindowLongSetWindowLong wieder zurückgeschrieben. Damit das Steuerelement die Änderung auch tatsächlich annimmt, muss anschließend noch die API-Funktion MSDN-Library - API SetWindowPosSetWindowPos aufgerufen werden. Dieser Aufruf mit dem speziellen Flag SWP_FRAMECHANGED teilt dem Steuerelement mit, dass sich sein Rahmen geändert hat. Die zusätzliche Kombination der Flags SWP_NOMOVE, SWP_NOSIZE, SWP_NOOWNERZORDER und SWP_NOZORDER zeigt dazu an, dass weder die Fensterreihenfolge noch die Größe oder Position des Steuerelements geändert werden sollen.

Alternative Rahmenstile für Steuerelemente

Alternative Rahmenstile für Steuerelemente

Die notwendigen Aufrufe fassen die beiden folgenden Prozeduren BorderStyleSunken und BorderStyleRaised zusammen. Setzen sie deren optionale Parameter Undo auf True, wird der betreffende Rahmenstil wieder rückgängig gemacht.

Private Const SWP_FRAMECHANGED = &H20
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOOWNERZORDER = &H200
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOZORDER = &H4

Private Declare Function GetWindowLong Lib "user32" _
 Alias "GetWindowLongA" (ByVal hWnd As Long, _
 ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" _
 Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, _
 ByVal dwNewLong As Long) As Long
Private Declare Function SetWindowPos Lib "user32" _
 (ByVal hWnd As Long, ByVal hWndInsertAfter As Long, _
 ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
 ByVal cy As Long, ByVal wFlags As Long) As Long

Public Sub BorderStyleSunken(ByVal hWnd As Long, _
 Optional ByVal Undo As Boolean)

  Dim nStyle As Long
  
  Const GWL_EXSTYLE = (-20)
  Const WS_EX_CLIENTEDGE = &H200&
  Const WS_EX_STATICEDGE = &H20000
  
  nStyle = GetWindowLong(hWnd, GWL_EXSTYLE)
  If Undo Then
    nStyle = nStyle And Not WS_EX_STATICEDGE
  Else
    nStyle = (nStyle Or WS_EX_STATICEDGE) And Not WS_EX_CLIENTEDGE
  End If
  SetWindowLong hWnd, GWL_EXSTYLE, nStyle
  SetWindowPos hWnd, 0, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE _
   Or SWP_NOOWNERZORDER Or SWP_NOZORDER Or SWP_FRAMECHANGED
End Sub

Public Sub BorderStyleRaised(ByVal hWnd As Long, _
 Optional ByVal Undo As Boolean)

  Dim nStyle As Long
  
  Const GWL_STYLE = (-16)
  Const WS_DLGFRAME = &H400000
  
  nStyle = GetWindowLong(hWnd, GWL_STYLE)
  If Undo Then
    nStyle = nStyle And Not WS_DLGFRAME
  Else
    nStyle = nStyle Or WS_DLGFRAME
  End If
  SetWindowLong hWnd, GWL_STYLE, nStyle
  SetWindowPos hWnd, 0, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE _
   Or SWP_NOOWNERZORDER Or SWP_NOZORDER Or SWP_FRAMECHANGED
End Sub

Sie können den Rahmen eines UserControls auf diese Weise ändern. Diese Art der Rahmensetzung hat den Vorteil, dass Sie sich keine Gedanken um die Innenmaße (ScaleWidth und ScaleHeight) zu machen brauchen, da diese automatisch angepasst werden.

Einen Doppelrahmen (wie in der Abbildung in der Mitte zu sehen), erhalten Sie, indem Sie die BorderStyle-Eigenschaft einer PictureBox oder eines UserControls auf 1 setzen. Dieser lässt sich allerdings nicht zurücksetzen.


Beispiel-Projekt und Modul modBorderStyle (borderstyle.zip - ca. 3,5 KB)


Artikel
Zum Download-Bereich dieses Artikel
Mail an den Autor dieses Artikels

KnowHow
Zur KnowHow-Übersicht

KnowHow-Themen
Themen - Allgemeines
Themen - Entwicklungsumgebung (VB-IDE)
Themen - Forms
Themen - Steuerelemente (Controls)
Themen - Grafik
Themen - Dateien
Themen - UserControls
Themen - Einsteiger-Tipps
Themen - Wussten Sie...?

Übersicht nach Titeln in alphabetischer Reihenfolge
Übersicht nach Erscheinungsdatum

Schnellsuche




Zum Seitenanfang

Copyright © 1999 - 2017 Harald M. Genauck, ip-pro gmbh  /  Impressum

Zum Seitenanfang

Zurück...

Zurück...

Download Internet Explorer